Ada 程式設計/庫/Ada.Text_IO.Editing

此語言功能從 Ada 95 開始可用。

Ada.Text_IO.Editing 是預定義語言環境中的一個單元，自 Ada 95 以來一直存在。

此包用於從表示某些貨幣金額的數字生成和列印字串。可以透過將 "" 作為引數傳遞來簡單地避免包含貨幣。

示例

with Ada.Text_IO.Editing;

procedure Example_Euros is

   type Euro_Price_Type is delta 0.01 digits 6;

   package Euros_IO is new Ada.Text_IO.Editing.Decimal_Output
     (Num                => Euro_Price_Type,
      Default_Currency   => "EUR ",
      Default_Fill       => ' ',
      Default_Separator  => ',',
      Default_Radix_Mark => '.');

   A_Price : constant Euro_Price_Type := 5873.26;
begin

   Ada.Text_IO.Put_Line ("Price with cents: ");

   --  We generate a string image and print it using Text_IO
   Ada.Text_IO.Put_Line
     (Euros_IO.Image
        (Item => A_Price,
         Pic  => Ada.Text_IO.Editing.To_Picture
           ("#_###_###_##9.99")));

   Ada.Text_IO.Put_Line ("Integer price: ");

   --  Let's use now the Put procedure from Euros_IO
   Euros_IO.Put
     (Item => A_Price,
      Pic  => Ada.Text_IO.Editing.To_Picture
        ("#_###_###_##9"));

end Example_Euros;

程式碼:

Price with cents:
    EUR 5,873.26
Integer price: 
    EUR 5,873

規範

--                     Standard Ada library specification
--   Copyright (c) 2003-2018 Maxim Reznik <reznikmm@gmail.com>
--   Copyright (c) 2004-2016 AXE Consultants
--   Copyright (c) 2004, 2005, 2006 Ada-Europe
--   Copyright (c) 2000 The MITRE Corporation, Inc.
--   Copyright (c) 1992, 1993, 1994, 1995 Intermetrics, Inc.
--   SPDX-License-Identifier: BSD-3-Clause and LicenseRef-AdaReferenceManual
-- -------------------------------------------------------------------------

package Ada.Text_IO.Editing is

   type Picture is private;

   function Valid (Pic_String      : in String;
                   Blank_When_Zero : in Boolean := False) return Boolean;

   function To_Picture (Pic_String      : in String;
                        Blank_When_Zero : in Boolean := False)
                       return Picture;

   function Pic_String      (Pic : in Picture) return String;
   function Blank_When_Zero (Pic : in Picture) return Boolean;

   Max_Picture_Length  : constant := implementation_defined;

   Picture_Error       : exception;

   Default_Currency    : constant String    := "$";
   Default_Fill        : constant Character := '*';
   Default_Separator   : constant Character := ',';
   Default_Radix_Mark  : constant Character := '.';

   generic
      type Num is delta <> digits <>;

      Default_Currency   : in String    := Text_IO.Editing.Default_Currency;
      Default_Fill       : in Character := Text_IO.Editing.Default_Fill;
      Default_Separator  : in Character := Text_IO.Editing.Default_Separator;
      Default_Radix_Mark : in Character := Text_IO.Editing.Default_Radix_Mark;
   package Decimal_Output is
      function Length (Pic      : in Picture;
                       Currency : in String := Default_Currency)
                      return Natural;

      function Valid (Item     : in Num;
                      Pic      : in Picture;
                      Currency : in String := Default_Currency)
                     return Boolean;

      function Image (Item       : in Num;
                      Pic        : in Picture;
                      Currency   : in String    := Default_Currency;
                      Fill       : in Character := Default_Fill;
                      Separator  : in Character := Default_Separator;
                      Radix_Mark : in Character := Default_Radix_Mark)
                     return String;

      procedure Put (File       : in File_Type;
                     Item       : in Num;
                     Pic        : in Picture;
                     Currency   : in String    := Default_Currency;
                     Fill       : in Character := Default_Fill;
                     Separator  : in Character := Default_Separator;
                     Radix_Mark : in Character := Default_Radix_Mark);

      procedure Put (Item       : in Num;
                     Pic        : in Picture;
                     Currency   : in String    := Default_Currency;
                     Fill       : in Character := Default_Fill;
                     Separator  : in Character := Default_Separator;
                     Radix_Mark : in Character := Default_Radix_Mark);

      procedure Put (To         : out String;
                     Item       : in Num;
                     Pic        : in Picture;
                     Currency   : in String    := Default_Currency;
                     Fill       : in Character := Default_Fill;
                     Separator  : in Character := Default_Separator;
                     Radix_Mark : in Character := Default_Radix_Mark);
   end Decimal_Output;

private
   pragma Import (Ada, Picture);
end Ada.Text_IO.Editing;

另請參閱

華夏公益教科書

Ada 程式設計/庫/Ada

Ada 風格指南

Ada 風格指南/可重用性#十進位制型別輸出和資訊系統附件

外部示例

在以下位置搜尋 Ada.Text_IO.Editing 的示例： Rosetta Code，GitHub (gists)，任何 Alire 包或此華夏公益教科書。
在以下位置搜尋與 Ada.Text_IO.Editing 相關的帖子： Stack Overflow，comp.lang.ada 或任何與 Ada 相關的頁面。

Ada 參考手冊

開源實現

FSF GNAT

規範： a-teioed.ads
主體： a-teioed.adb

drake

規範： textio/a-teioed.ads
主體： textio/a-teioed.adb

示例

規範

另請參閱

華夏公益教科書

Ada 風格指南

外部示例

Ada 參考手冊

Ada 95

Ada 2005

Ada 2012

開源實現