SPARQL/WIKIDATA 語言連結和徽章

語言連結

#Female scientists with most number of sitelinks (but not English Wikipedia)
SELECT ?item ?itemLabel (COUNT(DISTINCT ?languagelink) AS ?linkcount) (SAMPLE( ?languagelink ) AS ?sample ) 
WHERE {
    ?item wdt:P31 wd:Q5.            # is a human 
    ?item wdt:P21 wd:Q6581072.      # gender female
    ?item wdt:P106 wd:Q901.         # occupation scientist
    ?languagelink schema:about ?item.
  FILTER NOT EXISTS {
    ?enlanguagelink schema:about ?item.
    ?enlanguagelink schema:inLanguage "en". 
    ?enlanguagelink schema:isPartOf <https://en.wikipedia.org/>
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de,es,ar,fr" }
}
GROUP BY ?item ?itemLabel
ORDER BY DESC(?linkcount)

試試看！

程式碼 schema:about 將專案連結到語言連結。
程式碼 schema:inLanguage 在語言連結中檢索語言。
程式碼 schema:isPartOf 在語言連結中檢索維基媒體專案，例如 <https://en.wikipedia.org/>。

徽章

徽章是一種附加到語言連結的標記，它可以識別例如文章是否在特定網站上是 精選文章徽章 (Q17437796)。它們不描述外部實體，而是描述特定網站上的頁面。

這裡有一個對維基媒體專案徽章進行排名的查詢。

SELECT ?wiki ?badge ?badgeLabel (COUNT(DISTINCT ?languagelink) AS ?count) (SAMPLE(?item) AS ?sample)
WHERE {
  ?languagelink schema:isPartOf ?wiki.
  ?languagelink wikibase:badge ?badge.
  ?languagelink schema:about ?item.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". 
                          ?badge rdfs:label ?badgeLabel.
                         }

}
GROUP BY ?wiki ?badge ?badgeLabel
ORDER BY DESC(?count)
LIMIT 100

試試看！

程式碼 schema:isPartOf（在語言連結中）檢索維基媒體專案，例如 <https://en.wikipedia.org/>。
程式碼 wikibase:badge（在語言連結中）檢索徽章，例如 精選文章徽章 (Q17437796)。
程式碼 schema:about 將專案連結到語言連結。